Georgia Wildfire Prevention/Georgia Wildfire Prevention.iso/mac/media/dirs/BackUp/Internet.dir/00006_Script_Button BehaviorButton Behavior__.ls

Text File | 2001-12-03 | 3KB | 73 lines

--This behavior flashes a member at a desired rate and also allows it to work as a link to another frame.
--PROPERTIES--
--Hot: The member switched to (hot state).
--FlashSpeed: The speed in which the sprite flashes measured in ticks (1/60th of a sec.)
--WhichFrame: The frame junped to if pushed. Zero keeps the current frame.
--Glowing: Lets the function know if the sprite is hot or cold.
--RollOvr: The member switched to when rolled-over.
--ButtonSound: The sound that will play when clicked. Channel 2 is reserved for short sounds.
--TimeTracker: Times out the seconds between flashes.
--SpNum: The sprite number of the sprite.
--MyNum: The Member's number

property MyColor, OrigColor, WhichFrame, RollOvr, AssocImage, ButtonSound, MovieControl, TimeTracker, SpNum, MyNum, webaddress

--Captures the spritenumber.
on new me
  SpNum = me.spritenum
  MyNum=sprite(SpNum).member.number
  OrigColor = member(MyNum).forecolor
end

--Creates the dialog box for the behavior.
on getpropertydescriptionlist me
  set pList = [#MyColor:[#comment: "Which color would you like to use for the RollOver?", #format: #integer, #range: [#min: 0, #max: 255], #default: 192], \
 #RollOvr: [#comment: "Which member would you like to use for the rollover?", #format: #string, #default: ""], \
 #AssocImage: [#Comment: "Which image is this member associated with?", #format: #string, #default: ""],\
 #ButtonSound:[#comment: "What sound would you like to play when the button is pressed?",#format:#string,#default:"Click"],\
 #MovieControl: [#comment: "Is this button used to control a movie?",#format: #string,#range: ["Play", "Pause","Stop","Rewind","Fast Forward", "No"],#default:"No"], \
 #WebAddress: [#Comment: "What address would you like the graphic to link to?", #format: #string, #default: ""],\
  #WhichFrame: [#comment: "Which frame would you like to jump to?", #format:#integer, default: "0"]]
  return plist
end

--This is for the rollover.
on mouseenter me
  if rollovr <> "" then
    sprite(SpNum).membernum = member(RollOvr).number
  end if
  if AssocImage <> "" then
    sendallsprites(#imagechange, AssocImage)
  end if
  member(MyNum).forecolor = MyColor
  sprite(SpNum).cursor = 280
  updateStage
end
on mouseleave me
  if rollovr <> "" then
    sprite(SpNum).membernum = member(MyNum).number
  end if
  member(MyNum).forecolor = OrigColor
  sprite(SpNum).cursor = 293
  --  Glowing = 0
  updateStage
end

--This goes to another frame and tells the movie what to do. Also plays the sound, if any.
on mousedown me
  if WhichFrame <> 0 then
    go to frame WhichFrame
  else if MovieControl <> "No" then
    sendallsprites (#MovieActionDown, MovieControl)
  end if
  if webaddress <> "" then
    gotoNetPage WebAddress
  end if
  if  ButtonSound <> "" then
    sound(2).play(member(ButtonSound))
  end if
  updatestage
end